Standing Electromagnetic Waves in a Cavity and the Fabry-Perot Interferometer

We define, from  Eqs. (8.11) in the text

In which P(t), Q(t) are given by 



Where A is a constant. Let’s choose the values A = (Subscript[A, 0])/(Subscript[ω, n]). In that case

ClearAll["Global`*"]
electric[n_,z_,t_]=Sqrt[8 π/L^2 /d]Sin[n π/d z] A Sin[n π c t/d  + ϕ];
magnetic[n_,z_,t_]=Sqrt[8 π/L^2/ d] Cos[n π/d z] A Cos[n π c t/d  + ϕ];

(* For the purpose of plotting fields, initialize parameters to the following values *)
A=1;d=2;L=(Sqrt[8 π]);c=1;ϕ=0;

zgrid:=Table[x,{x,0,d,0.04}];
ndim:=Dimensions[zgrid][[1]];
e1[n_,t_]:=electric[n,zgrid,t];
b1[n_,t_]:=magnetic[n,zgrid,t];
vert[n_,t_]:=Table[Arrow[{{zgrid[[i]],0,0},{zgrid[[i]],0,e1[n,t][[i]]}}],{i,1,ndim}];
horz[n_,t_]:=Table[Arrow[{{zgrid[[i]],0,0},{zgrid[[i]],b1[n,t][[i]],0}}],{i,1,ndim}];

Below we illustrate the spatial and temporal dependence of the electric and magnetic fields given by Eq. (1) for node values n=1,2,3,4.

Manipulate[Graphics3D[{RGBColor[0.8,0.89,1],Cuboid[{0,-0.5,-0.5},{0.01,0.5,0.5}],Cuboid[{2.0,-0.5,-0.5},{2.0+0.05,0.5,0.5}],Arrowheads[0.005],Red,vert[n,t],Black,horz[n,t]},PlotRange->{{0,2},{-1.2,1.2},{-1.2,1.2}},Boxed->False,ViewPoint->{0.7,-0.5,0.5},ViewAngle->60 Degree],{t,0,4},{n,{1,2,3,4}},SaveDefinitions->True]

Fabry-Perot Instrument

In a Fabry-Perot instrument, the cavity mirrors allow some transmission of light. Here a light beam (usually a laser beam) enters the cavity through the mirror on the left. After entering the cavity, the light is momentarily trapped in the cavity before escaping through both mirrors. For arbitrary values of cavity thickness  d , the trapping probability is small. However, for  values of d that satisfy  resonance condition Eq. (8.10) in the text, the trapping probability is large and leads to an enhanced  electric and magnetic fields within the cavity. The simulation below illustrates this phenomenon for a 1D cavity.

Toggle for code

Clear[Ein,k,k2,k3,z1,d1,t];
ee1[z_]=Ein Exp[I k z] + Er Exp[-I k z];
ee2[z_]=c1 Exp[I k2 (z-z1)] + c2 Exp[-I k2 (z-z1)];
ee3[z_]= c3 Exp[I k (z-z1-t)]+c4 Exp[-I k (z-z1-t)];
ee4[z_]=c5 Exp[I k3(z-z1-d1-t)]+ c6 Exp[-I k3(z-z1-d1-t)];
ee5[z_]=Et Exp[I k (z-z1-d1-2t)];
eq1=ee1[z1]==ee2[z1];
eq2=ee1'[z1]==ee2'[z1];
eq3=ee2[z1+t]==ee3[z1+t];
eq4=ee2'[z1+t]==ee3'[z1+t];
eq5=ee3[z1+t+d1]==ee4[z1+t+d1];
eq6=ee3'[z1+t+d1]==ee4'[z1+t+d1];
eq7=ee4[z1+2t+d1]==ee5[z1+2t+d1];
eq8=ee4'[z1+2t+d1]==ee5'[z1+2t+d1];

sols=Simplify[Flatten[Solve[{eq1,eq2,eq3,eq4,eq5,eq6,eq7,eq8},{c1,c2,c3,c4,c5,c6,Er,Et}]] ];
f1[z_,d1_]=ee1[z] /. sols; 
f2[z_,d1_]=ee2[z] /. sols;
f3[z_,d1_]=ee3[z] /. sols;
f4[z_,d1_]=ee4[z] /. sols;
f5[z_,d1_]=ee5[z] /. sols;

For plotting purposes, we fix initial conditions for the laser parameters and geometry. The incoming wavenumber is given by k, the incident wave amplitude Ein, and k2 is the wavenumber inside the reflective surfaces (modeled by an imaginary value), t is the thickness of the reflecting material,

Ein=1;k=2;k2=100 I;k3=100 I;z1=0;t=0.01;
wave[z_,d1_]:=Piecewise[{{Re[f1[z,d1]],z<=z1},{Re[f2[z,d1]],z1<z<= z1+t},{Re[f3[z,d1]],z1+t<z<z1+t+d1},{Re[f4[z,d1]],z1+t+d1<z<z1+d1+2t},{Re[f5[z,d1]],z>z1+d1+2 t}}]

In the pair of figures shown below, the 1D electric field value is plotted (blue line) as it enters the cavity, bounded by two mirrors (red lines) . In the first diagram the thickness of the cavity does not meet the resonance condition and the fields are mainly reflected by the first mirror, while there is modest transmission through the barrier. In the diagram below it, we adjusted the cavity thickness d in such a way that a resonance condition is met. Here we find a significant enhancement in the field within the confines of the cavity. Note the small reflection and transmission proclivities when the resonance condition is met. Can you guess the mode, n, that is excited in this figure?

In the simulation below, adjust the cavity dimension d1 (with the slider) in order to find the resonant modes of the cavity.

Manipulate[Plot[wave[z,d1],{z,-10,10},PlotRange->All,Axes->False,Prolog->{Thickness[0.01],Red,Line[{{0,-10},{0,10}}],Thickness[0.01],Line[{{d1,-10},{d1,10}}]}],{d1,0,10,0.001},SaveDefinitions->True]