GHZ - States

The Bell inequalities demonstrate how the results of measurements of a quantum system cannot, in general, be reproduced by a local-realistic hidden variable model. However, Bell experiments require statistical analysis of an ensemble of measurement results to make this point.  In 1989, Daniel Greenberger,  Michael Horn and Anton Zeilinger (GHZ) introduced a protocol in which a four qubit system exhibits EPR-like ``spooky “ correlations, without the need of a statistical description.  An accessible synopsis of that effort can be found here.   MouseOver

In this notebook we discuss a similar, but simpler, 3-qubit description first introduced by N. David Mermin1.This system is assumed to be in the quantum state

(* up represent the \[LeftBracketingBar]0 ⟩ ket *) 
up={1,0};
(* down the \[LeftBracketingBar]1⟩ ket *)
down={0,1};
(* σX,σY,σZ are the Pauli operators, and unit the single-qubit identity operator*)
σX={{0,1},{1,0}};
σY={{0,-I},{I,0}};
σZ={{1,0},{0,-1}};
unit={{1,0},{0,1}};

The matrix representation for |ψ ⟩ is given by

psi=1/Sqrt[2](Flatten[KroneckerProduct[up,up,up]]-Flatten[KroneckerProduct[down,down,down]])

We introduce three measurement devices.  Bob and Alice posses the first and second qubits respectively, and use the Pauli-Y measuring device to measure their qubit assignments; the Pauli operator eigenvalues ±1.  Charles has possession of the third qubit but uses the Pauli-X device to measure his qubit. Recent advances MouseOver  
have demonstrated that entangled qubits can be shared over great distances. So Bob could be in Las Vegas, Charles in Tokyo, and Alice in Capetown, yet  their respective qubits share a common quantum state.

(* the aformentioned measuring devices are defined below *)
Bob=KroneckerProduct[unit,unit,σY];
Alice=KroneckerProduct[unit,σY,unit];
Charles=KroneckerProduct[σX,unit,unit];

We wish to simulate this experiment, so we need to use the Born rule in order to predict the probability for an event. First we predict the probability that Bob measures the choices ∓1 with his Pauli-Y device. We therefore need to construct the projection operators (see Notebook 1.3)
 
 
corresponding to the measuring projection operators for Bob’s device. The sums correspond to sum over degenerate eigenstates with eigenvalues ±1, respectively.

(* Bbasis are the basis vectors for Bob's measuring device *)
Bbasis=Eigensystem[Bob][[2]]/Sqrt[2];
(* MB[m] represents Bob's projective measuring device, for values m=±1 *)
Bminus=Sum[KroneckerProduct[Conjugate[Bbasis[[i]]],Bbasis[[i]]],{i,1,4}];
Bplus=Sum[KroneckerProduct[Conjugate[Bbasis[[i]]],Bbasis[[i]]],{i,5,8}];
MB[m_]:=Which[m==1,Bplus,m==-1,Bminus]

(* MA[m] represents Alice's projective measuring device, for values m=±1 *)
Abasis=Eigensystem[Alice][[2]]/Sqrt[2];
Aminus=Sum[KroneckerProduct[Conjugate[Abasis[[i]]],Abasis[[i]]],{i,1,4}];
Aplus=Sum[KroneckerProduct[Conjugate[Abasis[[i]]],Abasis[[i]]],{i,5,8}];
MA[m_]:=Which[m==1,Aplus,m==-1,Aminus]

(* MC[m] represents Charles's projective measuring device, for values m=±1 *)
Cbasis=Eigensystem[Charles][[2]]/Sqrt[2];
Cminus=Sum[KroneckerProduct[Conjugate[Cbasis[[i]]],Cbasis[[i]]],{i,1,4}];
Cplus=Sum[KroneckerProduct[Conjugate[Cbasis[[i]]],Cbasis[[i]]],{i,5,8}];
MC[m_]:=Which[m==1,Cplus,m==-1,Cminus]

The projection operator M(m1,m2,m3), defined below, allows us to calculate the probability that Charles obtains measured value m3, Alice m3, and Bob m1.

M[m1_,m2_,m3_]:=MC[m3].MB[m2].MA[m1]

Measurement with this operator leads to the projected states (e.g. see Notebook (1.3) )

projectedstate[m1_,m2_,m3_]:=If[Conjugate[psi].M[m1,m2,m3].psi==0,Table[0,{k,1,8}],M[m1,m2,m3].psi/(Sqrt[Conjugate[psi].M[m1,m2,m3].psi])]

(* Table of the eight different measurement outcomes with the corresponding projected states *)
TextGrid[{{"m1"," m2","m3","                 Projected state" }}] 
Grid[Flatten[Table[{m1,m2,m3,projectedstate[m1,m2,m3]},{m3,-1,1,2},{m2,-1,1,2},{m1,-1,1,2}],2 ],Frame->All]

We can now use the Born rule to calculate the various outcome probabilities, and employ the latter for a simulation.

(* p[m1,m2,m3] gives the probability of the outcomes tabulated above *)
p[m1_,m2_,m3_]:=Abs[Conjugate[projectedstate[m1,m2,m3]].psi]^2

choices=Flatten[Table[{m1,m2,m3},{m1,-1,1,2},{m2,-1,1,2},{m3,-1,1,2}],2];
measurementZ1:=RandomChoice[Apply[p,choices,1]->choices]

Running function measurementZ1 gives the output for the sequence where Charles measures with the Pauli-X device qubit 3, and Alice and Bob measure qubits 2,1, with PauliY

measurementZ1

Let’s tabulate the results of a sequence of twenty such (independent) measurements with the system always in state |ψ⟩.

Table[measurementZ1,{i,1,20}] // Column

Do you notice a pattern here ?  It appears no matter the sequence of qubit values, the product of the three qubit measurements (i.e. the parity) is always +1. There is a perfect correlation among the measurement outcomes so that their product is always +1. So if I know two out of the three measurement values, I can predict with 100% certainty the outcome of the other qubit, prior to measurement. This reminds us of Bertlmann’s socks. There is nothing spooky about guessing the color of Bertlmann’s sock, if we are given information about the color of the other sock.  According to Einstein et al.

“ If, without in any way disturbing a system, we can predict with certainty (i.e., a probability equal to unity) the value of a physical quantity, then there exist an element of physical reality to this physical quality. 2“  If we apply this definition toward our experiment, as we can predict with certainty an outcome without in any way disturbing the object (i.e. the qubit), we may conclude that our measuring devices does indeed reveal  properties of objects that constitute a “physical reality”.  In other words, if we believe in the above assumption, we should be able to reproduce the above data set using a classical local-realistic mechanism (e.g. Mermin’s reality machine). Convince your self that is indeed the case.

The fact that the above data describes the said correlations, can be shown in a more direct manner. Instead of uncovering the value for each of Alice, Bob and Charles measurements, we simply measure the eigenvalues of the operator,

which have the values ±1. Now

M1=KroneckerProduct[σX,σY,σY];
MatrixForm[M1]

(*and we find that *)
M1.psi==psi

That is, the GHZ state |ψ⟩ is an eigenstate of (Subscript[M, 1]) with eigenvalue +1, in harmony with the results of our measurement outcomes itemized above. In a classical local realistic description we would replace operator (Subscript[M, 1]) with a random variable (see Notebook 1.2) (Subscript[M, 1]), and  relation (1) with
({{
({{(Subscript[M, 1])}})= (Subscript[X, 3]) (Subscript[Y , 2])(Subscript[Y, 1])}})

where X, Y, Y represent the values of  the measurements revealed by Charles,  Alice and Bob respectively. For the values of X,Y,Y  observed we find that the value of the random variable  (Subscript[M, 1]) always takes on the value +1.  Convince yourself that the argument given above also applies to measurements in which Alice chooses to perform an X measurement and Bob and Charles pursue a Y measurement. Hence we define
({{
({{(Subscript[M, 2])}})= (Subscript[Y, 3]) (Subscript[X , 2])(Subscript[Y, 1])}})
Finally we posit the measurement 
({{({{(Subscript[M, 3])}})= (Subscript[Y, 3]) (Subscript[Y , 2])(Subscript[X, 1])}})

The product (Subscript[M, 1])(Subscript[M, 2])(Subscript[M, 3])=  (Subscript[X, 3]) (Subscript[Y , 2])(Subscript[Y, 1]) (Subscript[Y, 3]) (Subscript[X , 2])(Subscript[Y, 1])(Subscript[Y, 3]) (Subscript[Y , 2])(Subscript[X, 1])= (Subscript[X, 3]) (Subscript[X, 2])(Subscript[X, 1])

where we used the fact that the products  (Subscript[Y , 2])(Subscript[Y , 2])=(Subscript[Y , 1])(Subscript[Y , 1])=1. Therefore, in a local realistic model

({{(Subscript[M, C])≡({{(Subscript[M, 1])(Subscript[M, 2])(Subscript[M, 3])=1= (Subscript[X, 3]) (Subscript[X, 2])(Subscript[X, 1])}})}})
Now, lets  construct the product   
({{(Subscript[({{M}}), Q])=(Subscript[σ, X]) ⊗ (Subscript[σ, X]) ⊗ (Subscript[σ, X])}})

MQ=KroneckerProduct[σX,σX,σX];

and operate on the GHZ state |ψ ⟩

MQ.psi

which we realize is  -|ψ⟩

MQ.psi==-psi

Therefore |ψ ⟩ is an eigenstate, with eigenvalue -1, of measurement device M.  Contrast this with the fact that its classical analog (Subscript[M, C])=1. Therefore we run into a contradiction. We cannot recreate the measurement outcomes, when the system is in a GHZ state, using a classical local realistic model.

1	N. David Mermin, Physics Today 43, 6, (1990); doi:10.1063/1.2810588

2	A. Einstein, B. Podolsky, N. Rosen, Phys. Rev. 47, 777 (1935)